Rules for integrands of the form(((d x))^m) (((a+b (x^2)+c (x^4)))^p)

x.  ∫(((d x))^m) (((b (x^2)+c (x^4)))^p)dx

1:  ∫(((d x))^m) (((b (x^2)+c (x^4)))^p)dx  when p∈ℤ

Derivation: Algebraic simplification

Basis: If  p∈ℤ, then (((b (x^2)+c (x^4)))^p)==(1/(d^(2 p))) (((d x))^(2 p)) (((b+c (x^2)))^p)

Rule 1.2.2.2.0.1: If  p∈ℤ, then

∫(((d x))^m) (((b (x^2)+c (x^4)))^p)dx  ⟶  (1/(d^(2 p))) ∫(((d x))^(m+2 p)) (((b+c (x^2)))^p)dx

Program code:

(* Int[(d_.*x_)^m_.*(b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/d^(2*p)*Int[(d*x)^(m+2*p)*(b+c*x^2)^p,x] /;
FreeQ[{b,c,d,m},x] && IntegerQ[p] *)

2:  ∫(((d x))^m) (((b (x^2)+c (x^4)))^p)dx  when p∉ℤ

Derivation: Piecewise constant extraction

Basis: (∂_x)((((b (x^2)+c (x^4)))^p)/((((d x))^(2 p))(((b+c (x^2)))^p)))==0

Rule 1.2.2.2.0.2: If  p∉ℤ, then

∫(((d x))^m) (((b (x^2)+c (x^4)))^p)dx  ⟶  ((((b (x^2)+c (x^4)))^p)/((((d x))^(2 p))(((b+c (x^2)))^p))) ∫(((d x))^(m+2 p)) (((b+c (x^2)))^p)dx

Program code:

(* Int[(d_.*x_)^m_.*(b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (b*x^2+c*x^4)^p/((d*x)^(2*p)*(b+c*x^2)^p)*Int[(d*x)^(m+2*p)*(b+c*x^2)^p,x] /;
FreeQ[{b,c,d,m,p},x] && Not[IntegerQ[p]] *)

1:  ∫x (((a+b (x^2)+c (x^4)))^p)dx

Derivation: Integration by substitution

Basis: x F[(x^2)]==(1/2) Subst[F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.2.2.2.1:

∫x (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/2) Subst[∫(((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/2*Subst[Int[(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,p},x]

2:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when p∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Rule 1.2.2.2.2: If  p∈(SuperPlus[ℤ]), then

∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ∫ExpandIntegrand[(((d x))^m) (((a+b (x^2)+c (x^4)))^p),x]dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  Int[ExpandIntegrand[(d*x)^m*(a+b*x^2+c*x^4)^p,x],x] /;
FreeQ[{a,b,c,d,m},x] && IGtQ[p,0] && Not[IntegerQ[(m+1)/2]]

3.  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0

x:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∈ℤ

Derivation: Algebraic simplification

Basis: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.2.2.3.1: If  (b^2)-4 a c==0 ∧ p∈ℤ, then

∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/(c^p))∫(((d x))^m) ((((b/2)+c (x^2)))^(2 p))dx

Program code:

(* Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/c^p*Int[(d*x)^m*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p] *)

2.  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

1.  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+4 p+5==0 ∧ p≠-(1/2)

1:  ∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+4 p+5==0 ∧ p<-1

Derivation: Square trinomial recurrence 2c with m+4 p+5==0

Rule 1.2.2.2.3.2.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+4 p+5==0 ∧ p<-1, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((2 (((d x))^(m+1)) (((a+b (x^2)+c (x^4)))^(p+1)))/(d(m+3) (2 a+b (x^2))))-(((((d x))^(m+1))(((a+b (x^2)+c (x^4)))^(p+1)))/(2 a d (m+3) (p+1)))

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  2*(d*x)^(m+1)*(a+b*x^2+c*x^4)^(p+1)/(d*(m+3)*(2*a+b*x^2)) - 
  (d*x)^(m+1)*(a+b*x^2+c*x^4)^(p+1)/(2*a*d*(m+3)*(p+1)) /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[m+4*p+5,0] && LtQ[p,-1]

2:  ∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+4 p+5==0 ∧ p≠-(1/2)

Derivation: Square trinomial recurrence 2c with m+4 p+5==0

Rule 1.2.2.2.3.2.1: If  (b^2)-4 a c==0 ∧ p∉ℤ ∧ m+4 p+5==0 ∧ p≠-(1/2), then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  (((((d x))^(m+1))(((a+b (x^2)+c (x^4)))^(p+1)))/(4 a d (p+1) (2p+1)))-(((((d x))^(m+1)) (2 a+b (x^2))(((a+b (x^2)+c (x^4)))^p))/(4 a d(2p+1)))

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^2+c*x^4)^(p+1)/(4*a*d*(p+1)*(2*p+1)) - 
  (d*x)^(m+1)*(2*a+b*x^2)*(a+b*x^2+c*x^4)^p/(4*a*d*(2*p+1)) /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[p]] && EqQ[m+4*p+5,0] && NeQ[p,-1/2]

?:  ∫(x^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p-(1/2)∈ℤ ∧ ((m-1)/2)∈ℤ

Derivation: Integration by substitution

Basis: If ((m-1)/2)∈ℤ, then (x^m)F[(x^2)]==(1/2) Subst[(x^((m-1)/2)) F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.2.2.2.5.1: If  (b^2)-4 a c==0 ∧ p-(1/2)∈ℤ ∧ ((m-1)/2)∈ℤ, then

∫(x^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/2) Subst[∫(x^((m-1)/2)) (((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  1/2*Subst[Int[x^((m-1)/2)*(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,p},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p-1/2] && IntegerQ[(m-1)/2] && (GtQ[m,0] || LtQ[0,4*p,-m-1])

2:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p-(1/2)∈ℤ ∧ m∈(SuperPlus[ℤ])                 Delete!

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^2)+c (x^4)))^(p+1))/((((b/2)+c (x^2)))^(2 (p+1))))==0

Rule 1.2.2.2.3.2.2: If  (b^2)-4 a c==0 ∧ p-(1/2)∈ℤ ∧ m∈(SuperPlus[ℤ]), then

∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((c (((a+b (x^2)+c (x^4)))^(p+1)))/((((b/2)+c (x^2)))^(2 (p+1))))∫(((d x))^m) ((((b/2)+c (x^2)))^(2 p))dx

Program code:

(* Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  c*(a+b*x^2+c*x^4)^(p+1)/(b/2+c*x^2)^(2*(p+1))*Int[(d*x)^m*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p-1/2] && IGeQ[m,2*p] *)

3:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c==0 ∧ p∉ℤ

Derivation: Piecewise constant extraction

Basis: If  (b^2)-4 a c==0, then (∂_x)((((a+b (x^2)+c (x^4)))^p)/((((b/2)+c (x^2)))^(2 p)))==0

Note: If  (b^2)-4 a c==0, then a+b z+c (z^2)==(1/c) ((((b/2)+c z))^2)

Rule 1.2.2.2.3.2.2: If  (b^2)-4 a c==0 ∧ p∉ℤ, then

∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  ((((a+b (x^2)+c (x^4)))^(FracPart[p]))/((c^(IntPart[p]))((((b/2)+c (x^2)))^(2 FracPart[p]))))∫(((d x))^m) ((((b/2)+c (x^2)))^(2 p))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (a+b*x^2+c*x^4)^FracPart[p]/(c^IntPart[p]*(b/2+c*x^2)^(2*FracPart[p]))*Int[(d*x)^m*(b/2+c*x^2)^(2*p),x] /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[b^2-4*a*c,0] && IntegerQ[p-1/2]

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^2+c*x^4)^FracPart[p]/(1+2*c*x^2/b)^(2*FracPart[p])*Int[(d*x)^m*(1+2*c*x^2/b)^(2*p),x] /;
FreeQ[{a,b,c,d,m,p},x] && EqQ[b^2-4*a*c,0] && Not[IntegerQ[2*p]]

4:  ∫(x^m) (((a+b (x^2)+c (x^4)))^p)dx  when ((m-1)/2)∈ℤ

Derivation: Integration by substitution

Basis: If ((m-1)/2)∈ℤ, then (x^m)F[(x^2)]==(1/2) Subst[(x^((m-1)/2)) F[x],x,(x^2)] (∂_x)(x^2)

Rule 1.2.2.2.5.1: If  ((m-1)/2)∈ℤ, then

∫(x^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (1/2) Subst[∫(x^((m-1)/2)) (((a+b x+c (x^2)))^p)dx,x,(x^2)]

Program code:

Int[x_^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_.,x_Symbol] :=
  1/2*Subst[Int[x^((m-1)/2)*(a+b*x+c*x^2)^p,x],x,x^2] /;
FreeQ[{a,b,c,p},x] && IntegerQ[(m-1)/2]

5:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when  (b^2)-4 a c≠0 ∧ m∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((d x))^m) F[x]==(k/d) Subst[(x^(k (m+1)-1))F[((x^k)/d)],x,(((d x))^(1/k))] (∂_x)(((d x))^(1/k))

Rule 1.2.2.2.6.1.2: If  (b^2)-4 a c≠0 ∧ m∈𝔽, let k=Denominator[m], then

∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  (k/d) Subst[∫(x^(k (m+1)-1)) (((a+((b (x^(2 k)))/(d^2))+((c (x^(4 k)))/(d^4))))^p) dx,x,(((d x))^(1/k))]

Program code:

Int[(d_.*x_)^m_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  With[{k=Denominator[m]},
  k/d*Subst[Int[x^(k*(m+1)-1)*(a+b*x^(2*k)/d^2+c*x^(4*k)/d^4)^p,x],x,(d*x)^(1/k)]] /;
FreeQ[{a,b,c,d,p},x] && NeQ[b^2-4*a*c,0] && FractionQ[m] && IntegerQ[p]

6.  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0

1:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m>1

Derivation: Trinomial recurrence 1b with A=0, B=1 and m=m-n

Rule 1.2.2.2.6.1.3.1: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m>1, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
((d(((d x))^(m-1)) (((a+b (x^2)+c (x^4)))^p) (2 b p+c (m+4 p-1) (x^2)))/(c (m+4 p+1)(m+4 p-1)))-
((2 p (d^2))/(c (m+4 p+1)(m+4 p-1)))∫(((d x))^(m-2)) (((a+b (x^2)+c (x^4)))^(p-1)) (a b(m-1)-(2 a c (m+4 p-1)-(b^2)(m+2 p-1)) (x^2))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  d*(d*x)^(m-1)*(a+b*x^2+c*x^4)^p*(2*b*p+c*(m+4*p-1)*x^2)/(c*(m+4*p+1)*(m+4*p-1)) - 
  2*p*d^2/(c*(m+4*p+1)*(m+4*p-1))*
    Int[(d*x)^(m-2)*(a+b*x^2+c*x^4)^(p-1)*Simp[a*b*(m-1)-(2*a*c*(m+4*p-1)-b^2*(m+2*p-1))*x^2,x],x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && GtQ[m,1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

2:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m<-1

Reference: G&R 2.160.2

Derivation: Trinomial recurrence 1a with A=1 and B=0

Rule 1.2.2.2.6.1.3.2: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m<-1, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  (((((d x))^(m+1))(((a+b (x^2)+c (x^4)))^p))/(d (m+1)))-((2 p)/((d^2) (m+1)))∫(((d x))^(m+2)) (b+2 c (x^2))(((a+b (x^2)+c (x^4)))^(p-1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^2+c*x^4)^p/(d*(m+1)) - 
  2*p/(d^2*(m+1))*Int[(d*x)^(m+2)*(b+2*c*x^2)*(a+b*x^2+c*x^4)^(p-1),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && LtQ[m,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

3:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p>0 ∧ m+4 p+1≠0

Derivation: Trinomial recurrence 1a with A=0, B=1 and m=m-n

Derivation: Trinomial recurrence 1b with A=1 and B=0

Rule 1.2.2.2.6.1.3.4: If  (b^2)-4 a c≠0 ∧ p>0 ∧ m+4 p+1≠0, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  (((((d x))^(m+1))(((a+b (x^2)+c (x^4)))^p))/(d (m+4 p+1)))+((2 p)/(m+4 p+1))∫(((d x))^m) (2 a+b (x^2))(((a+b (x^2)+c (x^4)))^(p-1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^2+c*x^4)^p/(d*(m+4*p+1)) + 
  2*p/(m+4*p+1)*Int[(d*x)^m*(2*a+b*x^2)*(a+b*x^2+c*x^4)^(p-1),x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[b^2-4*a*c,0] && GtQ[p,0] && NeQ[m+4*p+1,0] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

7.  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1

1.  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ m>1

1:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ 1<m≤3

Derivation: Trinomial recurrence 2a with A=1 and B=0

Derivation: Trinomial recurrence 2b with A=0, B=1 and m=m-n

Rule 1.2.2.2.6.1.4.1.1: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ 1<m≤3, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
((d (((d x))^(m-1))(b+2 c (x^2))(((a+b (x^2)+c (x^4)))^(p+1)))/(2(p+1) ((b^2)-4 a c) ))-((d^2)/(2(p+1) ((b^2)-4 a c) ))∫(((d x))^(m-2))(b(m-1)+2c(m+4 p+5) (x^2))(((a+b (x^2)+c (x^4)))^(p+1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  d*(d*x)^(m-1)*(b+2*c*x^2)*(a+b*x^2+c*x^4)^(p+1)/(2*(p+1)*(b^2-4*a*c)) - 
  d^2/(2*(p+1)*(b^2-4*a*c))*Int[(d*x)^(m-2)*(b*(m-1)+2*c*(m+4*p+5)*x^2)*(a+b*x^2+c*x^4)^(p+1),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && GtQ[m,1] && LeQ[m,3] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

2:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1 ∧ m>3

Derivation: Trinomial recurrence 2a with A=0, B=1 and m=m-n

Rule 1.2.2.2.6.1.4.1.2: If  (b^2)-4 a c≠0 ∧ p<-1 ∧ m>3, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
-(((d^3)(((d x))^(m-3))(2 a+b (x^2))(((a+b (x^2)+c (x^4)))^(p+1)))/(2(p+1) ((b^2)-4 a c)))+((d^4)/(2(p+1) ((b^2)-4 a c) ))∫(((d x))^(m-4)) (2 a(m-3)+b(m+4p+3) (x^2)) (((a+b (x^2)+c (x^4)))^(p+1))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  -d^3*(d*x)^(m-3)*(2*a+b*x^2)*(a+b*x^2+c*x^4)^(p+1)/(2*(p+1)*(b^2-4*a*c)) + 
  d^4/(2*(p+1)*(b^2-4*a*c))*Int[(d*x)^(m-4)*(2*a*(m-3)+b*(m+4*p+3)*x^2)*(a+b*x^2+c*x^4)^(p+1),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && GtQ[m,3] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

2:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ p<-1

Derivation: Trinomial recurrence 2b with A=1 and B=0

Rule 1.2.2.2.6.1.4.2: If  (b^2)-4 a c≠0 ∧ p<-1, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
-(((((d x))^(m+1))((b^2)-2 a c+b c (x^2))(((a+b (x^2)+c (x^4)))^(p+1)))/(2 a d (p+1) ((b^2)-4 a c)))+
(1/(2 a (p+1)((b^2)-4 a c) ))∫(((d x))^m) (((a+b (x^2)+c (x^4)))^(p+1)) ((b^2)(m+2 p+3)-2a c(m+4 p+5)+b c(m+4 p+7)(x^2))dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  -(d*x)^(m+1)*(b^2-2*a*c+b*c*x^2)*(a+b*x^2+c*x^4)^(p+1)/(2*a*d*(p+1)*(b^2-4*a*c)) + 
  1/(2*a*(p+1)*(b^2-4*a*c))*
    Int[(d*x)^m*(a+b*x^2+c*x^4)^(p+1)*Simp[b^2*(m+2*p+3)-2*a*c*(m+4*p+5)+b*c*(m+4*p+7)*x^2,x],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[b^2-4*a*c,0] && LtQ[p,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

8:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ m>3 ∧ m+4 p+1≠0

Reference: G&R 2.160.3

Derivation: Trinomial recurrence 3a with A=0, B=1 and m=m-n

Note: G&R 2.174.1 is a special case of G&R 2.160.3.

Rule 1.2.2.2.6.1.5: If  (b^2)-4 a c≠0 ∧ m>3 ∧ m+4 p+1≠0, then

∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  ⟶  
(((d^3) (((d x))^(m-3))(((a+b (x^2)+c (x^4)))^(p+1)))/(c (m+4 p+1)))-((d^4)/(c (m+4 p+1)))∫(((d x))^(m-4)) (a(m-3)+b(m+2p-1)(x^2)) (((a+b (x^2)+c (x^4)))^p)dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  d^3*(d*x)^(m-3)*(a+b*x^2+c*x^4)^(p+1)/(c*(m+4*p+1)) - 
  d^4/(c*(m+4*p+1))*
    Int[(d*x)^(m-4)*Simp[a*(m-3)+b*(m+2*p-1)*x^2,x]*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,d,p},x] && NeQ[b^2-4*a*c,0] && GtQ[m,3] && NeQ[m+4*p+1,0] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

9:  ∫(((d x))^m) (((a+b (x^2)+c (x^4)))^p)dx  when (b^2)-4 a c≠0 ∧ m<-1

Reference: G&R 2.160.1

Derivation: Trinomial recurrence 3b with A=1 and B=0

Note: G&R 2.161.6 is a special case of G&R 2.160.1.

Rule 1.2.2.2.6.1.6: If  (b^2)-4 a c≠0 ∧ m<-1, then

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  
(((((d x))^(m+1)) (((a+b (x^2)+c (x^4)))^(p+1)))/(a d (m+1)))-(1/(a (d^2) (m+1))) ∫(((d x))^(m+2)) (b (m+2 p+3)+c (m+4 p+5) (x^2))(((a+b (x^2)+c (x^4)))^p)dx

Program code:

Int[(d_.*x_)^m_*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  (d*x)^(m+1)*(a+b*x^2+c*x^4)^(p+1)/(a*d*(m+1)) - 
  1/(a*d^2*(m+1))*Int[(d*x)^(m+2)*(b*(m+2*p+3)+c*(m+4*p+5)*x^2)*(a+b*x^2+c*x^4)^p,x] /;
FreeQ[{a,b,c,d,p},x] && NeQ[b^2-4*a*c,0] && LtQ[m,-1] && IntegerQ[2*p] && (IntegerQ[p] || IntegerQ[m])

10.  ∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0

1:  ∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m<-1

Reference: G&R 2.176, CRC 123

Derivation: Algebraic expansion

Basis: ((((d z))^m)/(a+b z+c (z^2)))==((((d z))^m)/a)-(1/(a d))(((((d z))^(m+1)) (b+c z))/(a+b z+c (z^2)))

Rule 1.2.2.2.6.1.7.1: If  (b^2)-4 a c≠0 ∧ m<-1, then

∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  ⟶  ((((d x))^(m+1))/(a d (m+1)))-(1/(a (d^2)))∫(((((d x))^(m+2)) (b+c (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(d_.*x_)^m_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  (d*x)^(m+1)/(a*d*(m+1)) -
  1/(a*d^2)*Int[(d*x)^(m+2)*(b+c*x^2)/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && LtQ[m,-1]

2.  ∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m>3

1:  ∫((x^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m>5 ∧ m∈ℤ

Derivation: Algebraic expansion

Rule 1.2.2.2.6.1.7.2.1: If  (b^2)-4 a c≠0 ∧ m>5 ∧ m∈ℤ, then

∫((x^m)/(a+b (x^2)+c (x^4)))dx  ⟶  ∫PolynomialDivide[(x^m),a+b (x^2)+c (x^4),x]dx

Program code:

Int[x_^m_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  Int[PolynomialDivide[x^m,(a+b*x^2+c*x^4),x],x] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && IGtQ[m,5]

2:  ∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m>3             Not necessary?

Reference: G&R 2.174.1, CRC 119

Derivation: Algebraic expansion

Basis: ((((d z))^m)/(a+b z+c (z^2)))==(((d^2)(((d z))^(m-2)))/c)-((d^2)/c)(((((d z))^(m-2)) (a+b z))/(a+b z+c (z^2)))

Rule 1.2.2.2.6.1.7.2.2: If  (b^2)-4 a c≠0 ∧ m>3, then

∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  ⟶  (((d^3) (((d x))^(m-3)))/(c (m-3)))-((d^4)/c)∫(((((d x))^(m-4)) (a+b (x^2)))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[(d_.*x_)^m_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  d^3*(d*x)^(m-3)/(c*(m-3)) - d^4/c*Int[(d*x)^(m-4)*(a+b*x^2)/(a+b*x^2+c*x^4),x] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && GtQ[m,3]

3.  ∫((x^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m∈(SuperPlus[ℤ])∧ 1≤m<4 ∧ (b^2)-4 a c≯0

1:  ∫((x^2)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c<0 ∧ a c>0

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(a/c)]), then ((x^2)/(a+b (x^2)+c (x^4)))==((q+(x^2))/(2(a+b (x^2)+c (x^4))))-((q-(x^2))/(2(a+b (x^2)+c (x^4))))

Note: Resulting integrands are of the form ((d+e (x^2))/(a+b (x^2)+c (x^4))) where c (d^2)-a (e^2)==0 ∧ (b^2)-4 a c≯0, for which there is rule.

Rule 1.2.2.2.6.1.7.3.1: If  (b^2)-4 a c<0 ∧ a c>0, let q->(Sqrt[(a/c)]), then

∫((x^2)/(a+b (x^2)+c (x^4)))dx  ⟶  (1/2)∫((q+(x^2))/(a+b (x^2)+c (x^4)))dx-(1/2)∫((q-(x^2))/(a+b (x^2)+c (x^4)))dx

Program code:

Int[x_^2/(a_+b_.*x_^2+c_.*x_^4), x_Symbol] :=
  With[{q=Rt[a/c,2]},
  1/2*Int[(q+x^2)/(a+b*x^2+c*x^4),x] - 1/2*Int[(q-x^2)/(a+b*x^2+c*x^4),x]] /;
FreeQ[{a,b,c},x] && LtQ[b^2-4*a*c,0] && PosQ[a*c]

2:  ∫((x^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m∈(SuperPlus[ℤ])∧ 3≤m<4 ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then ((z^3)/(a+b (z^2)+c (z^4)))==((q+r z)/(2 c r (q+r z+(z^2))))-((q-r z)/(2 c r (q-r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.2.2.6.1.7.3.2: If  (b^2)-4 a c≠0 ∧ m∈(SuperPlus[ℤ])∧ 3≤m<4 ∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫((x^m)/(a+b (x^2)+c (x^4)))dx  ⟶  (1/(2 c r))∫(((x^(m-3)) (q+r x))/(q+r x+(x^2)))dx-(1/(2 c r))∫(((x^(m-3)) (q-r x))/(q-r x+(x^2)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*r)*Int[x^(m-3)*(q+r*x)/(q+r*x+x^2),x] - 
  1/(2*c*r)*Int[x^(m-3)*(q-r*x)/(q-r*x+x^2),x]]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && GeQ[m,3] && LtQ[m,4] && NegQ[b^2-4*a*c]

3:  ∫((x^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m∈(SuperPlus[ℤ])∧ 1≤m<3 ∧ (b^2)-4 a c≯0

Derivation: Algebraic expansion

Basis: If  q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then (z/(a+b (z^2)+c (z^4)))==(1/(2 c r (q-r z+(z^2))))-(1/(2 c r (q+r z+(z^2))))

Note: If (a|b|c)∈ℝ ∧ (b^2)-4 a c<0, then (a/c)>0 and 2 (Sqrt[(a/c)])-(b/c)>0.

Rule 1.2.2.2.6.1.7.3.3: If  (b^2)-4 a c≠0 ∧ m∈(SuperPlus[ℤ])∧ 1≤m<3 ∧ (b^2)-4 a c≯0, let q->(Sqrt[(a/c)]) and r->(Sqrt[2 q-(b/c)]), then

∫((x^m)/(a+b (x^2)+c (x^4)))dx  ⟶  (1/(2 c r))∫((x^(m-1))/(q-r x+(x^2)))dx-(1/(2 c r))∫((x^(m-1))/(q+r x+(x^2)))dx

Program code:

Int[x_^m_./(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[a/c,2]},
  With[{r=Rt[2*q-b/c,2]},
  1/(2*c*r)*Int[x^(m-1)/(q-r*x+x^2),x] - 1/(2*c*r)*Int[x^(m-1)/(q+r*x+x^2),x]]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && GeQ[m,1] && LtQ[m,3] && NegQ[b^2-4*a*c]

4:  ∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0 ∧ m≥2

Reference: G&R 2.161.1a & G&R 2.161.3

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then ((((d z))^m)/(a+b z+c (z^2)))==(d/2) ((b/q)+1)((((d z))^(m-1))/((b/2)+(q/2)+c z))-(d/2) ((b/q)-1)((((d z))^(m-1))/((b/2)-(q/2)+c z))

Rule 1.2.2.2.6.1.7.4: If  (b^2)-4 a c≠0 ∧ m≥2, let q->(Sqrt[(b^2)-4 a c]), then

∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  ⟶  ((d^2)/2) ((b/q)+1)∫((((d x))^(m-2))/((b/2)+(q/2)+c (x^2)))dx-((d^2)/2) ((b/q)-1)∫((((d x))^(m-2))/((b/2)-(q/2)+c (x^2)))dx

Program code:

Int[(d_.*x_)^m_/(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  d^2/2*(b/q+1)*Int[(d*x)^(m-2)/(b/2+q/2+c*x^2),x] - 
  d^2/2*(b/q-1)*Int[(d*x)^(m-2)/(b/2-q/2+c*x^2),x]] /;
FreeQ[{a,b,c,d},x] && NeQ[b^2-4*a*c,0] && GeQ[m,2]

5:  ∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  when (b^2)-4 a c≠0

Reference: G&R 2.161.1a

Derivation: Algebraic expansion

Basis: Let q->(Sqrt[(b^2)-4 a c]), then (1/(a+b z+c (z^2)))==(c/q)(1/((b/2)-(q/2)+c z))-(c/q)(1/((b/2)+(q/2)+c z))

Rule 1.2.2.2.6.1.7.5: If  (b^2)-4 a c≠0, let q->(Sqrt[(b^2)-4 a c]), then

∫((((d x))^m)/(a+b (x^2)+c (x^4)))dx  ⟶  (c/q)∫((((d x))^m)/((b/2)-(q/2)+c (x^2)))dx-(c/q)∫((((d x))^m)/((b/2)+(q/2)+c (x^2)))dx

Program code:

Int[(d_.*x_)^m_./(a_+b_.*x_^2+c_.*x_^4),x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  c/q*Int[(d*x)^m/(b/2-q/2+c*x^2),x] - c/q*Int[(d*x)^m/(b/2+q/2+c*x^2),x]] /;
FreeQ[{a,b,c,d,m},x] && NeQ[b^2-4*a*c,0]

11.  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0

1.  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0

1:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ c<0

Derivation: Algebraic expansion

Basis: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then  (Sqrt[a+b (x^2)+c (x^4)])==(1/(2 (Sqrt[-c]))) (Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])

Rule 1.2.2.2.6.1.8.1.1: If  (b^2)-4 a c>0 ∧ c<0, let q->(Sqrt[(b^2)-4 a c]), then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  2 (Sqrt[-c])∫((x^2)/((Sqrt[b+q+2 c (x^2)]) (Sqrt[-b+q-2 c (x^2)])))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  2*Sqrt[-c]*Int[x^2/(Sqrt[b+q+2*c*x^2]*Sqrt[-b+q-2*c*x^2]),x]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && LtQ[c,0]

2.  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ c≮0

1:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0

Derivation: Algebraic expansion

Rule 1.2.2.2.6.1.8.1.2.1: If  (b^2)-4 a c>0 ∧ (c/a)>0 ∧ (b/a)<0, let q->(Sqrt[(c/a)]), then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (1/q) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(1/q) ∫((1-q (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,2]},
  1/q*Int[1/Sqrt[a+b*x^2+c*x^4],x] - 1/q*Int[(1-q*x^2)/Sqrt[a+b*x^2+c*x^4],x]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && GtQ[c/a,0] && LtQ[b/a,0]

2:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ a<0 ∧ c>0

Derivation: Algebraic expansion

Rule 1.2.2.2.6.1.8.1.2.2: If  (b^2)-4 a c>0 ∧ a<0 ∧ c>0, let q->(Sqrt[(b^2)-4 a c]), then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -((b-q)/(2 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(1/(2 c)) ∫((b-q+2 c (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  -(b-q)/(2*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + 1/(2*c)*Int[(b-q+2*c*x^2)/Sqrt[a+b*x^2+c*x^4],x]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0] && LtQ[a,0] && GtQ[c,0]

3.  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b±(Sqrt[(b^2)-4 a c]))/a)>0

1:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)>0

Reference: G&R 3.153.1+

Rule 1.2.2.2.6.1.8.1.2.3.1: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if ((b+q)/a)>0, then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((x (b+q+2 c (x^2)))/(2 c (Sqrt[a+b (x^2)+c (x^4)])))-(((Sqrt[((b+q)/(2 a))]) (2 a+(b+q) (x^2)) (Sqrt[((2 a+(b-q) (x^2))/(2 a+(b+q) (x^2)))]))/(2 c (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[ArcTan[(Sqrt[((b+q)/(2 a))]) x],((2 q)/(b+q))]

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  x*(b+q+2*c*x^2)/(2*c*Sqrt[a+b*x^2+c*x^4]) - 
  Rt[(b+q)/(2*a),2]*(2*a+(b+q)*x^2)*Sqrt[(2*a+(b-q)*x^2)/(2*a+(b+q)*x^2)]/(2*c*Sqrt[a+b*x^2+c*x^4])*
    EllipticE[ArcTan[Rt[(b+q)/(2*a),2]*x],2*q/(b+q)] /;
 PosQ[(b+q)/a] && Not[PosQ[(b-q)/a] && SimplerSqrtQ[(b-q)/(2*a),(b+q)/(2*a)]]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

2:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)>0

Reference: G&R 3.153.1-

Rule 1.2.2.2.6.1.8.1.2.3.2: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if ((b-q)/a)>0 then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  ((x (b-q+2 c (x^2)))/(2 c (Sqrt[a+b (x^2)+c (x^4)])))-(((Sqrt[((b-q)/(2 a))]) (2 a+(b-q) (x^2)) (Sqrt[((2 a+(b+q) (x^2))/(2 a+(b-q) (x^2)))]))/(2 c (Sqrt[a+b (x^2)+c (x^4)]))) EllipticE[ArcTan[(Sqrt[((b-q)/(2 a))]) x],-((2 q)/(b-q))]

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  x*(b-q+2*c*x^2)/(2*c*Sqrt[a+b*x^2+c*x^4]) - 
  Rt[(b-q)/(2*a),2]*(2*a+(b-q)*x^2)*Sqrt[(2*a+(b+q)*x^2)/(2*a+(b-q)*x^2)]/(2*c*Sqrt[a+b*x^2+c*x^4])*
    EllipticE[ArcTan[Rt[(b-q)/(2*a),2]*x],-2*q/(b-q)] /;
 PosQ[(b-q)/a]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

4.  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b±(Sqrt[(b^2)-4 a c]))/a)≯0

1:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b+(Sqrt[(b^2)-4 a c]))/a)≯0

Derivation: Algebraic expansion

Rule 1.4.1.8.1.2.4.1: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b+q)/a)≯0 then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -((b+q)/(2 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(1/(2 c)) ∫((b+q+2 c (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  -(b+q)/(2*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + 1/(2*c)*Int[(b+q+2*c*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NegQ[(b+q)/a] && Not[NegQ[(b-q)/a] && SimplerSqrtQ[-(b-q)/(2*a),-(b+q)/(2*a)]]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

2:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c>0 ∧ ((b-(Sqrt[(b^2)-4 a c]))/a)≯0

Derivation: Algebraic expansion

Rule 1.4.1.8.1.2.4.2: If  (b^2)-4 a c>0, let q->(Sqrt[(b^2)-4 a c]), if  ((b-q)/a)≯0 then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  -((b-q)/(2 c)) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx+(1/(2 c)) ∫((b-q+2 c (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  -(b-q)/(2*c)*Int[1/Sqrt[a+b*x^2+c*x^4],x] + 1/(2*c)*Int[(b-q+2*c*x^2)/Sqrt[a+b*x^2+c*x^4],x] /;
 NegQ[(b-q)/a]] /;
FreeQ[{a,b,c},x] && GtQ[b^2-4*a*c,0]

2.  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≱0

1:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)>0

Derivation: Algebraic expansion

Rule 1.2.2.2.6.1.8.2.1: If  (b^2)-4 a c≠0 ∧ (c/a)>0, let q->(Sqrt[(c/a)]), then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (1/q) ∫(1/(Sqrt[a+b (x^2)+c (x^4)]))dx-(1/q) ∫((1-q (x^2))/(Sqrt[a+b (x^2)+c (x^4)]))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[c/a,2]},
  1/q*Int[1/Sqrt[a+b*x^2+c*x^4],x] - 1/q*Int[(1-q*x^2)/Sqrt[a+b*x^2+c*x^4],x]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && PosQ[c/a]

2:  ∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  when (b^2)-4 a c≠0 ∧ (c/a)≯0

Derivation: Piecewise constant extraction

Basis: If  q->(Sqrt[(b^2)-4 a c]), then  (∂_x)(((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))==0

Rule 1.2.2.2.6.1.8.2.2: If  (b^2)-4 a c≠0 ∧ (c/a)≯0, let q->(Sqrt[(b^2)-4 a c]), then

∫((x^2)/(Sqrt[a+b (x^2)+c (x^4)]))dx  ⟶  (((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))]))/(Sqrt[a+b (x^2)+c (x^4)]))∫((x^2)/((Sqrt[1+((2 c (x^2))/(b-q))]) (Sqrt[1+((2 c (x^2))/(b+q))])))dx

Program code:

Int[x_^2/Sqrt[a_+b_.*x_^2+c_.*x_^4],x_Symbol] :=
  With[{q=Rt[b^2-4*a*c,2]},
  Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]/Sqrt[a+b*x^2+c*x^4]*
    Int[x^2/(Sqrt[1+2*c*x^2/(b-q)]*Sqrt[1+2*c*x^2/(b+q)]),x]] /;
FreeQ[{a,b,c},x] && NeQ[b^2-4*a*c,0] && NegQ[c/a]

12:  ∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx

Derivation: Piecewise constant extraction

Basis: (∂_x)(( (((a+b (x^2)+c (x^4)))^p))/((((1+((2 c (x^2))/(b+(Sqrt[(b^2)-4 a c])))))^p) (((1+((2 c (x^2))/(b-(Sqrt[(b^2)-4 a c])))))^p)))==0

Rule 1.2.2.2.10:

∫(((d x))^m)(((a+b (x^2)+c (x^4)))^p)dx  ⟶  (( (a^(IntPart[p])) (((a+b (x^2)+c (x^4)))^(FracPart[p])))/((((1+((2 c (x^2))/(b+(Sqrt[(b^2)-4 a c])))))^(FracPart[p])) (((1+((2 c (x^2))/(b-(Sqrt[(b^2)-4 a c])))))^(FracPart[p])))) ∫(((d x))^m)(((1+((2 c (x^2))/(b+(Sqrt[(b^2)-4 a c])))))^p) (((1+((2 c (x^2))/(b-(Sqrt[(b^2)-4 a c])))))^p)dx

Program code:

Int[(d_.*x_)^m_.*(a_+b_.*x_^2+c_.*x_^4)^p_,x_Symbol] :=
  a^IntPart[p]*(a+b*x^2+c*x^4)^FracPart[p]/
    ((1+2*c*x^2/(b+Rt[b^2-4*a*c,2]))^FracPart[p]*(1+2*c*x^2/(b-Rt[b^2-4*a*c,2]))^FracPart[p])*
    Int[(d*x)^m*(1+2*c*x^2/(b+Sqrt[b^2-4*a*c]))^p*(1+2*c*x^2/(b-Sqrt[b^2-4*a*c]))^p,x] /;
FreeQ[{a,b,c,d,m,p},x]

S:  ∫(u^m) (((a+b (v^2)+c (v^4)))^p)dx  when  v==d+e x ∧ u==f v

Derivation: Integration by substitution and piecewise constant extraction

Basis: If  u==f v, then (∂_x)((u^m)/(v^m))==0

Rule 1.2.2.2.S: If  v==d+e x ∧ u==f v, then

∫(u^m) (((a+b (v^2)+c (v^4)))^p)dx  ⟶  ((u^m)/(e (v^m)))Subst[∫(x^m) (((a+b (x^2)+c (x^4)))^p)dx,x,v]

Program code:

Int[u_^m_.*(a_.+b_.*v_^2+c_.*v_^4)^p_.,x_Symbol] :=
  u^m/(Coefficient[v,x,1]*v^m)*Subst[Int[x^m*(a+b*x^2+c*x^(2*2))^p,x],x,v] /;
FreeQ[{a,b,c,m,p},x] && LinearPairQ[u,v,x]